jfcampos, te debo una cena cuando subas para Madrid, tio, mil gracias por la ayuda
Al final he logrado que se ejecute la animacion, pasando del play y el boton (por lo que veo eso nos lo permite el sponsor, gracias a Dios) y logro que se reproduzca la animación llegando al final, detenerla y dejar el audio de fondo sonar hasta terminar. Ha quedado perfecto
Dejo el codigo de mi clase Sponsor extendida con la clase FlxState de Flixel para quien pueda servirle de ayuda en un futuro:
package
{
import Menu.MenuScreen;
import org.flixel.FlxState;
import org.flixel.FlxG;
import flash.display.MovieClip;
import flash.media.SoundMixer;
import flash.events.Event;
public class Sponsor extends FlxState
{
// SWF embebido y haciendo referencia al simbolo que queremos reproducir:
[Embed(source='../Content/Sponsor/4v4_logo\'snoPLAY.swf', symbol='Logo')]
private var logo:Class;
private var movie:MovieClip = new logo;
private var _event:String = Event.ENTER_FRAME;
// Contador de espera adicional. Como en este caso la animacion es más corta que la duración del audio de fondo implementaremos un
// contador de pasos en el metodo de actualización del objeto estado de Flixel:
private var counter:int = -1;
override public function create():void
{
// Reubicamos la escena en pantalla:
movie.x = 285;
movie.y = 220;
// Añadimos el movieclip a la instancia de Flixel:
FlxG.stage.addChild(movie);
// Añadimos el evento de escucha no al movieclip si no al simbolo que se reproduce (logon no aparece listado por FlashDevelop):
movie.logon.addEventListener(_event, listener);
}
// Evento para controlar el final de la animacion:
private function listener(e:Event):void
{
// Cuando el indice del fotograma actual sea el mismo que el numero de fotogramas del simbolo...
if (e.target.currentFrame == e.target.totalFrames)
{
// Eliminamos el evento del simbolo:
movie.logon.removeEventListener(_event, listener);
// Detenemos la reproducción del simbolo. El audio seguira reproduciendose:
movie.logon.stop();
// Establecemos un valor al contador para la espera adicional para el audio:
counter = 465;
}
}
// El metodo update controlara el tiempo extra que le damos al SWF para terminar de reproducir el audio de fondo y cambiar al siguiente estado del juego:
override public function update():void
{
// Descontamos un paso en el contador de espera adicional:
if (counter > 0) counter--;
// Cuando el contador llegue a cero detenemos el audio pendiente y eliminamos el movieclip de la instancia:
if (counter == 0)
{
SoundMixer.stopAll();
FlxG.stage.removeChild(movie);
// Saltamos al menu del juego:
FlxG.switchState(new MenuScreen());
}
super.update();
}
}
}En este caso mi desconocimiento sobre Flash ha jugado muy en contra mía al igual que no saber que FlashDevelop a veces no lista en el código todos los elementos de un objeto, como en este caso, símbolos del SWF que no lista el explorador de soluciones del IDE.
Gracias a todos por vuestra ayuda y tiempo
Salu2...
